如何在 Go Gazelle 项目中使用 Bazel 平台转换

怎么入门Golang编程？需要学习哪些知识点？这是新手们刚接触编程时常见的问题；下面golang学习网就来给大家整理分享一些知识点，希望能够给初学者一些帮助。本篇文章就来介绍《如何在 Go Gazelle 项目中使用 Bazel 平台转换》，涉及到，有需要的可以收藏一下

我有一个使用 gazelle 设置的（纯）go 项目。它有一个主要的二进制文件，由 gazelle 生成的 cmd/main/build 如下所示：

load("@io_bazel_rules_go//go:def.bzl", "go_binary", "go_library")

go_library(
    name = "main_lib",
    srcs = ["main.go"],
    importpath = "github.com/me/myrepo/....",
    visibility = ["//visibility:private"],
    deps = [
        "//pkg/api",
        "//pkg/archive",
        ...
    ],
)

go_binary(
    name = "main",
    embed = [":main_lib"],
    visibility = ["//visibility:public"],
)

我可以通过在命令行上传递 --platforms=@io_bazel_rules_go//go/toolchain:linux_arm64 来为我的主机系统或我们的部署目标构建二进制文件。 但现在，我希望能够创建一个包含两个平台构建的 tar，而无需使用不同的 cli 参数调用 bazel。

按照此处的建议（“您可以通过 //command_line_option:platforms 上的 bazel 配置转换等效地依赖 go_binary 或 go_test 规则”），我正在尝试使用转换来进行设置。

我的 transitions.bzl 文件：

# build opts for development machine
def _host_transition_impl(settings, attr):
    _ignore = (settings, attr)
    return {
        "//command_line_option:platforms": "@io_bazel_rules_go//go/toolchain:linux_amd64",
        "//command_line_option:compilation_mode": "fastbuild",
    }

# build opts for deployment target
def _target_transition_impl(settings, attr):
    _ignore = (settings, attr)
    return {
        "//command_line_option:platforms": "@io_bazel_rules_go//go/toolchain:linux_arm64",
        "//command_line_option:compilation_mode": "opt",
    }

host_transition = transition(
    implementation = _host_transition_impl,
    inputs = [],
    outputs = ["//command_line_option:platforms", "//command_line_option:compilation_mode"],
)

target_transition = transition(
    implementation = _target_transition_impl,
    inputs = [],
    outputs = ["//command_line_option:platforms", "//command_line_option:compilation_mode"],
)

def _impl(ctx):
    return []

host_transitioning_rule = rule(
    implementation = _impl,
    cfg = host_transition,
    attrs = {
        "_allowlist_function_transition": attr.label(
            default = "@bazel_tools//tools/allowlists/function_transition_allowlist",
        ),
    },
)

target_transitioning_rule = rule(
    implementation = _impl,
    cfg = target_transition,
    attrs = {
        "_allowlist_function_transition": attr.label(
            default = "@bazel_tools//tools/allowlists/function_transition_allowlist",
        ),
    },
)

但现在，我不知道如何将转换附加到 gazelle 生成的 go_binary 规则。我的根构建文件：

load("@bazel_gazelle//:def.bzl", "gazelle")

load(":transitions.bzl", "host_transitioning_rule", "target_transitioning_rule")

load("@bazel_tools//tools/build_defs/pkg:pkg.bzl", "pkg_tar")

# gazelle:prefix github.com/me/mypath...
gazelle(name = "gazelle")

gazelle(
    name = "gazelle-update-repos",
    args = [
        "-from_file=go.mod",
        "-to_macro=deps.bzl%go_dependencies",
        "-prune",
        "-build_file_proto_mode=disable_global",
    ],
    command = "update-repos",
)

host_transitioning_rule(
    name = "mainHost",
    # TODO: how to attach this to //cmd/main:main
)

target_transitioning_rule(
    name = "mainTarget",
    # TODO: how to attach this to //cmd/main:main
)

pkg_tar(
    name = "release",
    srcs = [
        ":mainHost",
        ":mainTarget",
    ],
    package_dir = "lib",
)

正确答案

只需转发其他规则中的相关 providers 即可。 FilesToRunProvider 和 DefaultInfo 通常是最重要的。您可以有效地重新创建 alias，并将过渡附加到 outgoing edge。如下所示：

def _impl(ctx):
    providers = []
    if defaultinfo in ctx.attr.dep:
        providers.append(ctx.attr.dep[defaultinfo])
    if filestorunprovider in ctx.attr.dep:
        providers.append(ctx.attr.dep[filestorunprovider])
    return providers

host_transitioning_rule = rule(
    implementation = _impl,
    attrs = {
        "_allowlist_function_transition": attr.label(
            default = "@bazel_tools//tools/allowlists/function_transition_allowlist",
        ),
        "dep": attr.label(cfg = host_transition),
    },
)

然后像这样使用它：

host_transitioning_rule(
    name = "mainHost",
    dep = "//cmd/main:main",
)

您尝试将过渡附加到传入边缘。这会改变规则本身的配置。在这种情况下并没有真正产生区别，因为规则仅具有单一依赖项，但如果您想将主机配置中的一个依赖项与目标中的一个依赖项（例如）结合起来，那么您将需要使用传出边缘转换在单独的属性上。

您可以迭代所有提供程序（例如 examples/blob/main/rules/attributes/printer.bzl）并将其全部转发，而不是查找特定提供程序。不过，对于某些提供商来说，这可能会有点棘手，所以我会避免这样做。例如，如果您在交叉编译时盲目转发 GoLibrary，您最终将尝试链接为不同架构编译的库，这是行不通的。

以上就是本文的全部内容了，是否有顺利帮助你解决问题？若是能给你带来学习上的帮助，请大家多多支持golang学习网！更多关于Golang的相关知识，也可关注golang学习网公众号。